home *** CD-ROM | disk | FTP | other *** search
/ CD ROM Paradise Collection 4 / CD ROM Paradise Collection 4 1995 Nov.iso / asm / alib11b.zip / CODE1.ZIP / DISKINFO / TRANSFER.ASM < prev   
Assembly Source File  |  1994-10-04  |  7KB  |  272 lines
  1. ;-----------------------------------------------------------------------
  2. ; LOW LEVEL DISK DRIVERS
  3. ;-----------------------------------------------------------------------
  4. ;  INPUTS -  ax=cluster#
  5. ;            es=storage area
  6. ;            cx=number of clusters to read
  7. ;
  8. ;   OUTPUT - carry set if error
  9. ;            all registers destroyed except for segment registers
  10. ;
  11. read_clusters:
  12.     test    ax,07
  13.     jnz    rcs4                ;jump if not display trigger
  14.     push    ax
  15.     push    bx
  16.     push    si
  17.     mov    dx,display_position3
  18.     call    display_dec_word_at_posn
  19.     pop    si
  20.     pop    bx    
  21.     pop    ax    
  22. rcs4:    sub    ax,2                ;force cluster count range (0 +)
  23.     mul    cs:sectors_per_cluster        ;compute sector#
  24.     sub    bp,bp
  25.     add    ax,cs:boot_fat_dir_size        ;add number sectors in header
  26.     adc    bp,dx                ;add in carry
  27.     push    ax                ;save sector#
  28.     mov    ax,cx
  29.     mul    cs:sectors_per_cluster        ;compute # of sectors to read
  30.     mov    cx,ax                ; -cx- = # of sectors to read
  31.     pop    dx                ; -dx- = sector #
  32.     sub    bx,bx                ;set buffer offset to zero
  33.     call    read_sectors
  34.     ret
  35. ;-------------------------------------------------------------------------
  36. ; read sectors
  37. ;  inputs:  cs:drive_number  
  38. ;           es:bx = buffer
  39. ;           cx = number of sectors to read
  40. ;        bp = relative sector number (high word)
  41. ;           dx = relative sector number (low word)
  42. ;  outputs: carry set if error
  43. ;
  44.  
  45. read_sectors:
  46.     push    si
  47.     push    di
  48.     push    ds
  49.     mov    al,cs:drive_number
  50.     mov    cs:buffer_sav,bx
  51.     mov    cs:seg_sav,es
  52.     mov    cs:count_sav,cx
  53.     mov    cs:sector_adr_sav,dx
  54.     mov    cs:sector_adr_sav+2,bp
  55.     push    es
  56.     pop    ds
  57.     int    25h            ;absoulute read
  58.     inc    sp            ;clear stack
  59.     inc    sp            ;clear stack
  60.     cld                ;restore direction
  61.     jnc    read_sectors_exit1    ;jmp if read ok
  62. ;
  63. ; first read failed.  If this is a DOS4+ extended partition (over 33meg) then
  64. ; we must use an alternate format for int 25
  65. ;
  66.     push    cs
  67.     pop    ds
  68.     mov    al,cs:drive_number    
  69.     mov    bx,offset dos4_int25_pkt
  70.     mov    cx,-1            ;sector# not here
  71.     int    25h            ;absoulute read
  72.     pop    ax            ;clear stack
  73.     cld                ;restore direction
  74.     jnc    read_sectors_exit1
  75.     mov    cs:bad_sector,dx        ;save bad sector#
  76.     cmp    cs:test_mode,0            ;check if real thing
  77.     je    read_sectors_exit1        ;  and keep going if it is
  78.     or    cs:abort_flag,1
  79.     stc
  80. read_sectors_exit1:
  81.     pop    ds
  82.     pop    di
  83.     pop    si
  84. read_exit:
  85.     ret
  86. ;---------------------
  87. ; read cluster using fat
  88. ;   INPUTS - ax = fat ptr
  89. ;            es = storage area
  90. ;            
  91. ;   OUTPUT - carry set if error
  92. ;            ax = ffff if last read was at end of fat chain.
  93. ;                 else, ax points at next fat entry
  94. ;
  95. read_using_fat:
  96.     push    es
  97.     call    fat_lookup            ;look up cluster in fat
  98.     pop    es
  99.     push    bx                ;save  next cluster number
  100.     mov    cx,1                ;read one cluster
  101.     call    read_clusters
  102.     pop    ax                ;get next cluster number
  103.     ret
  104.  
  105. ;---------------------
  106. ;  INPUTS -  ax=cluster#
  107. ;            es=storage area
  108. ;            cx=number of clusters to write
  109. ;  OUTPUT - carry set if error
  110. ;           all registers destroyed except for ES & DS
  111. ;
  112. write_clusters:
  113.     test    ax,07
  114.     jnz    wcs4                ;jump if not display trigger
  115.     push    ax
  116.     push    bx
  117.     push    si
  118.     mov    dx,display_position1
  119.     call    display_dec_word_at_posn
  120.     pop    si
  121.     pop    bx    
  122.     pop    ax    
  123. wcs4:    sub    ax,2                ;force cluster count range (0 +)
  124.     mul    cs:sectors_per_cluster        ;compute sector#
  125.     sub    bp,bp
  126.     add    ax,cs:boot_fat_dir_size        ;add number sectors in header
  127.     adc    bp,dx                ;add any carry
  128.     push    ax                ;save sector#
  129.     mov    ax,cx
  130.     mul    cs:sectors_per_cluster        ;compute # of sectors to write
  131.     mov    cx,ax                ; -cx- = # of sectors to write
  132.     pop    dx                ; -dx- = sector #
  133.     call    write_sectors
  134.     ret
  135. ;--------------------------- 
  136. ;  INPUTS -   cx = number of sectors to write
  137. ;             bp,dx = sector number 
  138. ;          es:bx = data buffer 
  139. ;            drive_number   
  140. ;  OUTPUTS-  carry set if error
  141. ; 
  142. write_sectors: 
  143.     push    si
  144.     push    di
  145.     push    ds
  146.     cmp    cs:test_mode,0            ;check if test mode
  147.     jnz    write_bypass            ;  and skip write if true
  148.     sub    bx,bx
  149.     mov    al,cs:drive_number
  150.     mov    cs:buffer_sav,bx
  151.     mov    cs:seg_sav,es
  152.     mov    cs:count_sav,cx
  153.     mov    cs:sector_adr_sav,dx
  154.     mov    cs:sector_adr_sav+2,bp
  155.     push    es
  156.     pop    ds
  157.     int    26h            ;absoulute write
  158.     inc    sp            ;clear stack
  159.     inc    sp            ;clear stack
  160.     cld                ;restore direction
  161.     jnc    writ_exit        ; jmp if read ok
  162. ;
  163. ; first writ failed.  If this is a DOS4+ extended partition (over 33meg) the
  164. ; we must use an alternate format for int 25
  165. ;
  166.     push    cs
  167.     pop    ds
  168.     mov    al,cs:drive_number
  169.     mov    bx,offset dos4_int25_pkt
  170.     mov    cx,-1            ;sector# not here
  171.     int    26h            ;absoulute read
  172.     pop    ax            ;clear stack
  173.     cld                ;restore direction
  174.     jnc    writ_exit
  175.     mov    cs:bad_sector,dx
  176.     or    cs:abort_flag,2
  177.     jmp    writ_exit
  178. write_bypass:
  179.     clc
  180. writ_exit:
  181.     pop    ds
  182.     pop    di
  183.     pop    si
  184.         ret 
  185.  
  186. ;------------------------------
  187. ; look up cluster in fat
  188. ;    INPUTS - ax = fat ptr from dir
  189. ;    OUTPUT - ax = cluster number
  190. ;             bx = next cluster number
  191. ;             es = fat segment
  192. fat_lookup:
  193.     mov    es,cs:fat_segment
  194.     cmp    cs:fat_type,1            ;check if 12-bit fat
  195.     je    twelve_bit_fat            ;jump if 12-bit fat
  196. ;
  197. ; 16-bit fat
  198. ;
  199.     mov    bx,ax                ;get fat ptr (cluster #)
  200.     shl    bx,1                ;convert to word index
  201.     mov    bx,es:[bx]            ;get next fat ptr
  202.     ret
  203. twelve_bit_fat:
  204.     mov    bx,ax
  205.     shr    bx,1
  206.     pushf
  207.     add    bx,ax
  208.     mov    bx,es:[bx]            ;get fat data
  209.     popf                    ;get odd/even state
  210.     jnc    twelve1                ;jump if even fat entry
  211.     shr    bx,1
  212.     shr    bx,1
  213.     shr    bx,1
  214.     shr    bx,1
  215. twelve1:and    bx,0fffh
  216.     jz    twelve3                ;jump if fat=0
  217.     cmp    bx,0ff7h            ;check if end
  218.     jl    twelve3                ;jump if not end of chain
  219.     jne    twelve2                ;jump if end of chain
  220.     mov    bx,0fff7h            ;get locked out cluster code
  221.     jmp    short twelve3
  222. twelve2:
  223.     mov    bx,0ffffh            ;set end of chain state
  224. twelve3:ret
  225. ;-------------------------------
  226. ; fat_write  
  227. ;   INPUTS  -  ax = fat (cluster#)
  228. ;              bx = new data
  229. ;
  230. fat_write:
  231.     push    es
  232.     push    bx
  233.     mov    es,cs:fat_segment
  234.     cmp    cs:fat_type,1            ;check if 12-bit fat
  235.     je    twelv_bit_fat            ;jump if 12-bit fat
  236. ;
  237. ; 16-bit fat
  238. ;
  239.     mov    bx,ax                ;get fat ptr (cluster #)
  240.     shl    bx,1                ;convert to word index
  241.     pop    ax
  242.     mov    es:[bx],ax            ;store new fat ptr
  243.     pop    es
  244.     ret
  245. twelv_bit_fat:
  246.     mov    bx,ax
  247.     shr    bx,1
  248.     pushf                    ;save carry flag
  249.     add    bx,ax                ;compute fat address
  250.     mov    cx,es:[bx]            ;get current fat data
  251.     popf                    ;restore carry flag
  252.     pop    ax                ;restore new fat data
  253.     jnc    twelv1                ;jump if even fat
  254.     and    ax,0fffh            ;force 12bit value
  255.     shl    ax,1
  256.     shl    ax,1
  257.     shl    ax,1
  258.     shl    ax,1
  259.     and    cx,000fh            ;remove old fat data
  260.     or    cx,ax
  261.     mov    es:[bx],cx
  262.     pop    es
  263.     ret
  264. twelv1:
  265.     and    ax,0fffh            ;force 12-bit value
  266.     and    cx,0f000h            ;remove old fat data
  267.     or    cx,ax
  268.     mov    es:[bx],cx
  269.     pop    es
  270.     ret
  271. ;-----------------------------------------------------------------------
  272.